SELECT Syntax

with-clause ::= 'WITH' alias 'AS' '(' ( select | expression ) ')'
                 ( ',' alias 'AS' '(' ( select | expression ) ')' )*

alias ::= identifier

select-clause ::= 'SELECT' hint-comment? projection

projection ::= ( 'ALL' | 'DISTINCT' )?
               ( result-expr ( ',' result-expr )* |
               ( 'RAW' | 'ELEMENT' | 'VALUE' ) expr ( 'AS'? alias )? )

result-expr ::= ( ( path '.' )? '*' | expr ( 'AS'? alias )? )

path ::= identifier ( '[' expr ']' )* ( '.' identifier ( '[' expr ']' )* )*

from-clause ::= 'FROM' from-terms

from-terms ::= ( from-keyspace | from-subquery | from-generic )
               ( join-clause | nest-clause | unnest-clause )*  comma-separated-join*

from-keyspace ::= keyspace-ref ( 'AS'? alias )? use-clause?

keyspace-ref ::= keyspace-path | keyspace-partial

keyspace-path ::= ( namespace ':' )? bucket ( '.' scope '.' collection )?

keyspace-partial ::= collection

namespace ::= identifier

bucket ::= identifier

scope ::= identifier

collection ::= identifier

from-subquery ::= subquery-expr 'AS'? alias

subquery-expr ::= '(' select ')'

from-generic ::= expr ( 'AS' alias )?

join-clause ::= ansi-join-clause | lookup-join-clause | index-join-clause

nest-clause ::= ansi-nest-clause | lookup-nest-clause | index-nest-clause

unnest-clause ::= unnest-type? ( 'UNNEST' | 'FLATTEN' ) expr ( 'AS'? alias )?

unnest-type ::= 'INNER' | ( 'LEFT' 'OUTER'? )

comma-separated-join ::= ',' ( rhs-keyspace | rhs-subquery | rhs-generic )

use-clause ::= use-keys-clause | use-index-clause

use-keys-clause ::= 'USE' use-keys-term

use-keys-term ::= 'PRIMARY'? 'KEYS' expr

use-index-clause ::= 'USE' use-index-term

use-index-term ::= 'INDEX' '(' index-ref ( ',' index-ref )* ')'

index-ref ::= index-name? index-type?

index-name ::= identifier

index-type ::= 'USING' ( 'GSI' | 'FTS' )

let-clause ::= 'LET' alias '=' expr ( ',' alias '=' expr )*

where-clause ::= 'WHERE' cond

cond ::= expr

group-by-clause ::= 'GROUP' 'BY' expr ( ',' expr )* letting-clause? having-clause? | letting-clause

letting-clause ::= 'LETTING' alias '=' expr ( ',' alias '=' expr )*

having-clause ::= 'HAVING' cond

window-clause ::= 'WINDOW' window-declaration ( ',' window-declaration )*

window-declaration ::= window-name 'AS' '(' window-definition ')'

window-name ::= identifier

window-definition ::= window-ref? window-partition-clause? window-order-clause?
                      window-frame-clause?

window-ref ::= identifier

window-partition-clause ::= 'PARTITION' 'BY' expr ( ',' expr )*

window-order-clause ::= 'ORDER' 'BY' ordering-term ( ',' ordering-term )*

window-frame-clause ::= ( 'ROWS' | 'RANGE' | 'GROUPS' ) window-frame-extent window-frame-exclusion?

window-frame-extent ::= 'UNBOUNDED' 'PRECEDING' | valexpr 'PRECEDING' | 'CURRENT' 'ROW' |
                        'BETWEEN' ( 'UNBOUNDED' 'PRECEDING' | 'CURRENT' 'ROW' |
                                     valexpr ( 'PRECEDING' | 'FOLLOWING' ) )
                            'AND' ( 'UNBOUNDED' 'FOLLOWING' | 'CURRENT' 'ROW' |
                                     valexpr ( 'PRECEDING' | 'FOLLOWING' ) )

window-frame-exclusion ::= 'EXCLUDE' ( 'CURRENT' 'ROW' | 'GROUP' | 'TIES' | 'NO' 'OTHERS' )

order-by-clause ::= 'ORDER' 'BY' ordering-term ( ',' ordering-term )*

ordering-term ::= expr ( 'ASC' | 'DESC' )? ( 'NULLS' ( 'FIRST' | 'LAST' ) )?

limit-clause ::= 'LIMIT' expr

offset-clause ::= 'OFFSET' expr